'ProgramMode:RUN
'Original by HP50G
'(c)2017 akatuki
Rad
ClrGraph
GridOff
AxesOff
LabelOff
ViewWindow 1,127,0,63,1,0

128->W:64->H:29->R
3->N

{N,1}->Dim Mat X
{N,1}->Dim Mat Y
{N,1}->Dim Mat T

{N,3}->Dim Mat x
{N,3}->Dim Mat y
{N,3}->Dim Mat v
{N,3}->Dim Mat w
{N,3}->Dim Mat t

'--- InitShip
For 1->I To N
 2pi*(I-1)/N->T[I]
 W/2+R*cos T[I]->X[I]
 H/2+R*sin T[I]->Y[I]
Next

0->F
Ticks->r
'--Loop
Lbl 0
Ticks->C
Cls

'--moveShip
For 1->I To N
 T[I]+.05->T[I]
 W/2+R*cos T[I]->X[I]
 H/2+R*sin T[I]->Y[I]

'--- DrawShip
 X[I]-6*sin T[I]->a
 Y[I]+6*cos T[I]->b
 X[I]+2*cos T[I]->c
 Y[I]+2*sin T[I]->d
 X[I]-2*cos T[I]->e
 Y[I]-2*sin T[I]->f

 F-Line a,b,c,d:
 F-Line a,b,e,f:
 F-Line c,d,e,f:

 For 1->J To 3
  If t[I,J]>0:Then
   x[I,J]+v[I,J]->x[I,J]
   y[I,J]+w[I,J]->y[I,J]
   PlotOn x[I,J],y[I,J]:
   t[I,J]-1->t[I,J]
  IfEnd
 Next
Next

KeyRow(3)->K
K&64=>Gosub S,1:' 4
K&32=>Gosub S,2:' 5
K&16=>Gosub S,3:' 6

' fps display
Isz F
If Ticks-r>=128:Then
 F->p
 0->F
 Ticks->r
IfEnd
Text 1,1,"fps ":
Text 1,14,p:

PutDispDD

' fps control
While Ticks-C<16
WhileEnd

Goto 0
Stop

'-- shootBlip
Lbl S
Local i
For 1->j To 3
 10->t[i,j]
 X[i]->x[i,j]
 Y[i]->y[i,j]
Next
 sin T[i]->v[i,1]
-cos T[i]->w[i,1]
 sin (T[i]-pi/3->v[i,2
-cos (T[i]-pi/3->w[i,2
 sin (T[i]+pi/3->v[i,3
-cos (T[i]+pi/3->w[i,3
Return